*   variable level xxx (scale) (ordinal) (nominal )     .


*   delete variable N_BREAK .
*   erase file  'delete1.sav'.

*   SAVE OUTFILE='.sav'
  /COMPRESSED.

*************.

*GET  FILE='.sav'

***************************                    *******************************.

cd 'C:\1 Barbados\analisys'  .

GET  FILE='kilocalories total and value for each hh.sav'.

COMPUTE cost_per_calorie=value_day_sum / calories_day_sum.
COMPUTE cost_2104calorie= 2104 *cost_per_calorie .
COMPUTE cost_2104calorie_month= cost_2104calorie * 365 / 12.
EXECUTE.

SORT CASES BY hhid(A).

SAVE OUTFILE='delete1.sav'
  /COMPRESSED.

***********.

GET  FILE= 'delete1.sav' .

**********************************************************************************************************.

GET  FILE= 'f1 agregate.sav'  .

SORT CASES BY hhid(A).

MATCH FILES /FILE=*
  /RENAME (clothing_pc comunication_pc education_pc entertaiment_pc furniture_pc h_services_pc 
    health_pc house_pc other_pc personal_pc = d0 d1 d2 d3 d4 d5 d6 d7 d8 d9) 
  /TABLE='C:\1 Barbados\analisys\delete1.sav'
  /RENAME (calories_day_sum hh_size hhid_string psu stratum value_day_sum weight = d10 d11 d12 d13 
    d14 d15 d16) 
  /BY hhid
  /DROP= d0 d1 d2 d3 d4 d5 d6 d7 d8 d9 d10 d11 d12 d13 d14 d15 d16.
EXECUTE.

WEIGHT OFF.


***139  households  do not have calorie content , do not use them for the calorie estimate . .

COMPUTE data_ok=0.
IF ( cost_2104calorie_month>0) data_ok=1.
EXECUTE.

***2,223 households 

***Select a the poor (this is an interactive process, at the end of the poverty determinatin, we run the program from here 
***, using the households bellow the poverty line, un, it againwith the new group, look at the results, run it  again, until the group and the
***results are within half a percentage point.  (the process is convergent) .

IF  (data_ok=1 and centil >= 10 and centil <= 26) reference1=1.
EXECUTE.

***Estimate the average cost fo the food basket for thos households .

IF  (reference1=1) cal_ref1=cost_2104calorie_month.
EXECUTE.

WEIGHT BY weight3.

AGGREGATE
  /OUTFILE=* MODE=ADDVARIABLES
  /BREAK=
  /cost_2104calorie_month_mean=MEAN(cal_ref1).

***For the total poverty line we select a second group of households, those with total consumption, close to the poverty line.

IF  ((cons_pc >= cost_2104calorie_month_mean * 0.9 )  and  (cons_pc < cost_2104calorie_month_mean * 
    1.1)  and data_ok=1 ) reference2=1.
EXECUTE.

***estimate the engels coeficient of this group .

IF  (reference2=1) engels_ref2= engels.
EXECUTE.

AGGREGATE
  /OUTFILE=* MODE=ADDVARIABLES
  /BREAK=
  /engels_ref2_mean_1=MEAN(engels_ref2).

COMPUTE line_extreme=cost_2104calorie_month_mean.
variable label line_extreme "Extreme poverty line/month/Per Capita" .
EXECUTE.

COMPUTE line_moderate=line_extreme / engels_ref2_mean_1.
variable label line_moderate "Moderate poverty line/month/Per Capita" .
EXECUTE.

***create the poverty clasifications .

COMPUTE poor_extreme=0.
IF  (cons_pc < line_extreme) poor_extreme=1.
EXECUTE.

COMPUTE poor_all=0.
IF  (cons_pc < line_moderate) poor_all=1.
EXECUTE.

COMPUTE poor=3.
IF  (poor_all = 1) poor=2.
IF  (poor_extreme = 1) poor=1.
EXECUTE.

FREQUENCIES VARIABLES=poor
  /ORDER=ANALYSIS.

Variable labels poor_extreme "Extreme Poor: consumption<extreme line".
Variable labels poor_all "All poor:  consumption< moderate line" . 
Variable labels poor "Extreme poor, non extreme poor and non poor" .

Value labels poor_extreme 0"Not extreme poor" 1"Extreme poor".
Value labels poor_all 0"Not poor" 1"Poor".
Value labels poor 1"Extreme poor" 2"Non-extreme poor" 3"Non poor"  .

variable level poor_extreme  poor_all (scale)      .

SAVE OUTFILE='g1 poverty.sav'
  /COMPRESSED.

***********.

GET  FILE= 'g1 poverty.sav' .

***********************************************************************************************.

GET  FILE= 'g1 poverty.sav' 
/ keep =hhid hhid_string psu stratum hh_size weight weight3 quintile decile 
    engels food_pc cons_pc nonfood_pc line_extreme line_moderate poor_extreme poor_all poor    .

***FGT(a) =  1/N * {SUM[(Poverty line-consumption(i))/poverty line]}^a
*** a = alfa 0, 1 o 2.   N = n# of persons,  consumption (i) = per capita consumption aggregate of poor households
***The formula is calculated without weights.  To get the values, the data has to get weighted (weight3) and mean values can be estimates

***Define variables:

compute pob_all  =  poor_all     .
compute pob_ext =  poor_extreme   .
compute li_all       =  line_moderate  .
compute li_ext     =   line_extreme  .
compute consumption =   cons_pc .
EXECUTE .

***For overall poverty.

COMPUTE sum_gen = 0 .
IF (pob_all = 1) sum_gen =  (li_all - consumption)/ li_all .

***For extreme poverty.

COMPUTE sum_ext = 0 .
IF (pob_ext = 1) sum_ext =  (li_ext - consumption)/ li_ext .
EXECUTE .

***to estimate the 3 meassures P0, 01, y p2 (for extreme and overall poverty) .

COMPUTE sum0gen =   1 *(sum_gen ** 0) .
COMPUTE sum1gen =   1 *(sum_gen ** 1) .
COMPUTE sum2gen =   1 *(sum_gen ** 2) .
EXECUTE .

COMPUTE sum0ext =   1 *(sum_ext ** 0) .
COMPUTE sum1ext =   1 *(sum_ext ** 1) .
COMPUTE sum2ext =   1 *(sum_ext ** 2).
EXECUTE .

***to change  "."to 0  for the  Sum0's   variables.

RECODE  sum0gen sum0ext  (SYSMIS=0)  .
EXECUTE .

variable labels
sum0gen 'P0 Headcount rate: all poor '/
sum1gen 'P1  Poverty gap index: all poor'/
sum2gen 'P2 Poverty gap squared: all poor'/
sum0ext 'P0 Headcount rate: extreme poor '/
sum1ext 'P1  Poverty gap index: extreme poor'/
sum2ext 'P2 Poverty gap squared: extreme poor' .

DELETE VARIABLES   pob_all pob_ext li_all li_ext consumption sum_gen sum_ext   .

RENAME VARIABLES ( sum0gen = p0 )  ( sum1gen = P1 )  ( sum2gen = p2 )  
( sum0ext = p0_ext )  ( sum1ext = p1_ext )  ( sum2ext = p2_ext )    .

VARIABLE LEVEL p0 P1 p2 p0_ext p1_ext p2_ext (SCALE).

rename variable (weight=weight2) .

variable labels weight2 "Sampling weight after droping households without consumption (final weight)".
variable labels weight3 "Weight2 *  hh_size".

variable labels  quintile "Population quintile  (5 groups)" .
variable labels  decile "Population decile (10 groups)" .
variable labels  food_pc  "Total food consumption/month/Per Capita" .
variable labels  cons_pc  "Total consumption in BB dollars/month/Per Capita" .

WEIGHT OFF.
SORT CASES BY hhid(A).

SAVE OUTFILE='g2 poverty.sav'
  /keep = hhid hhid_string psu stratum hh_size weight2 weight3 quintile decile food_pc 
    nonfood_pc cons_pc line_extreme line_moderate poor_extreme poor_all poor p0 P1 p2 p0_ext p1_ext 
    p2_ext.

***********.

GET  FILE= 'g2 poverty.sav' .

DESCRIPTIVES VARIABLES=hhid psu stratum hh_size weight2 weight3 quintile decile food_pc nonfood_pc 
    cons_pc line_extreme line_moderate poor_extreme poor_all poor p0 P1 p2 p0_ext p1_ext p2_ext
  /STATISTICS=MEAN SUM STDDEV MIN MAX.

WEIGHT BY weight3.

DESCRIPTIVES VARIABLES=hhid psu stratum hh_size weight2 weight3 quintile decile food_pc nonfood_pc 
    cons_pc line_extreme line_moderate poor_extreme poor_all poor p0 P1 p2 p0_ext p1_ext p2_ext
  /STATISTICS=MEAN SUM STDDEV MIN MAX.

WEIGHT BY weight2.

DESCRIPTIVES VARIABLES=hhid psu stratum hh_size weight2 weight3 quintile decile food_pc nonfood_pc 
    cons_pc line_extreme line_moderate poor_extreme poor_all poor p0 P1 p2 p0_ext p1_ext p2_ext
  /STATISTICS=MEAN SUM STDDEV MIN MAX.

  erase file  'delete1.sav'.